(comment) @comment

[
  "include"
  "build"
  "build_defaults"
  "build_linux"
  "build_windows"
  "build_darwin"
  "toolchains"
  "binary"
  "sources"
  "timeout"
  "memory_limit"
  "group"
  "test"
  "pattern"
] @keyword

[
  "normalize_crlf"
  "trim_trailing_ws"
] @keyword

(build_scalar_field  name: _ @property)
(build_list_field    name: _ @property)
(bool_decl           name: _ @property)
(legacy_build_platform keyword: _ @keyword)

[
  "profile"
  "warnings"
  "define"
  "platforms"
  "binary"
  "class"
  "weight"
  "scoring"
  "wrapper"
  "env"
  "stdin"
  "stdout"
  "stderr"
  "args"
  "exitCode"
  "file"
  "outFile"
  "input"
  "output"
  "dirs"
] @property

[
  "linux"
  "windows"
  "darwin"
] @type.builtin

(profile_value)  @constant.builtin
(warnings_value) @constant.builtin
(scoring_value)  @constant.builtin
(class_value)    @constant.builtin
(bool)           @constant.builtin

"of" @keyword.operator

[
  "contains"
  "matches"
  "anyOrder"
] @function.builtin

[
  "="
  "~"
] @operator

[
  "{"
  "}"
  "("
  ")"
] @punctuation.bracket

(simple_string)  @string
(heredoc_string) @string
(regex_string)   @string.regex

(structured_build name: (string) @string.special)
(legacy_build     command: (string) @string.special)
(toolchain_entry  name: (string) @type)
(toolchain_entry  name: (identifier) @type)
(group            name: (string) @string.special)
(test             name: (string) @string.special)
(include          path: (string) @string.special.path)

(define_field  key: (string) @constant.macro)
(env_decl      key: (string) @constant.macro)
(file_decl     key: (string) @string.special.path)
(out_file_decl key: (string) @string.special.path)